' 1 UPARIVAC
' DEFDBL A-H, O-Z
CLS
PRINT "Laboratorij za mjerenja, regulaciju i automatizaciju"
PRINT "PREHRAMBENO BIOTEHNOLO[KI FAKULTET"
PRINT "----------------------------------------------------"
PRINT
PRINT "          VJE@BA IZ MATEMATI^KOG MODELIRANJA I VO\ENJA PROCESA"
PRINT "             UPARAVANJE NARAN^INOG SOKA S JEDNIM UPARIVA^EM"
PRINT
PRINT
PRINT "ZADAJTE SLIJEDE]E PODATKE PREMA UPUTAMA ZA VJE@BU"
PRINT
10 REM
INPUT "MASENI PROTOK SOKA NARAN^E NA ULAZU U UPARIVA^ (kg/h) ="; Qso
IF Qso < 15000 OR QS > 20000 THEN PRINT "15 t/h <= Qs <= 20 t/h ": GOTO 10
20 REM
INPUT "TEMPERATURA SOKA NARAN^E NA ULAZU U UPARIVA^    T (C) ="; Tso
IF Tso < 15 OR Tso > 25 THEN PRINT "15 <= T(C) <= 25 ": GOTO 20
30 REM
INPUT "MASENI UDIO SUHE TVARI U ULAZNOM SOKU NARAN^E x (kg/kg) ="; xo
IF xo < .09 OR xo > .12 THEN PRINT "0.09 <= xo <= 0.12 ": GOTO 30
40 REM
INPUT "TEMPERATURA ZASI]ENE VODENE PARE NA ULAZU         T (C) ="; Tpo
IF Tpo < 120 OR Tpo > 125 THEN PRINT "120 <= Tpo(C) <= 125 ": GOTO 40
50 REM
INPUT "MASENI PROTOK ZASI]ENE VODENE PARE           Qp (kg/h) ="; Qp
IF Qp < 12000 OR Qp > 13000 THEN PRINT "12 t/h <= Qp <= 13 t/h": GOTO 50
CLS
PRINT "ZADANI SU SLIJEDE]I PODACI"
PRINT "-----------------------------------------------------------------"
PRINT
PRINT "MASENI PROTOK SOKA NARAN^E NA ULAZU U UPARIVA^  (kg/h) ="; Qso
PRINT "TEMPERATURA SOKA NARAN^E NA ULAZU U UPARIVA^     T (C) ="; Tso
PRINT "MASENI UDIO SUHE TVARI U ULAZNOM SOKU NARAN^E x (kg/kg) ="; xo
PRINT "TEMPERATURA ZASI^ENE VODENE PARE NA ULAZU        T (C) ="; Tpo
PRINT "MASENI PROTOK ZASI^ENE VODENE PARE              (kg/h)="; Qp
PRINT "-----------------------------------------------------------------"
PRINT
PRINT
INPUT "Da li su podaci ispravno zadani (*/n)"; r$
IF r$ = "n" OR r$ = "N" THEN GOTO 10

S = 266
ho = 1576: ho = ho * 3.6
h1 = -1091: h1 = h1 * 3.6
cs = 1.491
cl = 4.1865
A = 2519.74
B = 1.584
DEF fnH (x) = ho + h1 * x
DEF fnCp (x) = cs * x + cl * (1 - x)
DEF fnip (T) = A + B * T
C = 4.1886
DEF fniv (T) = C * T
LS = Qso * fnCp(xo) * Tso + Qp * fnip(Tpo)
T = 100
CLS
PRINT "RJE[AVANJE BILANCI NEWTON-RHAPSONOVOM ITERATIVNOM METODOM"
PRINT "---------------------------------------------------------"
1000 REM start iter
x = (Qp * (fnip(Tpo) - fniv(T)) / S / (Tpo - T) - ho) / h1
QL = Qso * xo / x
QV = Qso * (1 - xo / x)
F = -LS + QV * fnip(T) + QL * fnCp(x) * T + Qp * fniv(T)
dxt = Qp / h1 / S * (-C * (Tpo - T) + fnip(Tpo) - fniv(T))
dxt = dxt / (Tpo - T) / (Tpo - T)
df = Qso * xo / x / x * (fnip(T) - fnCp(x) * T) + QL * (cs - cl) * T
df = df * dxt + QV * B + QL * fnCp(x) + Qp * C
T = T - F / df
PRINT "x="; x, "T="; T
INPUT "Nova iteracija (*/n) "; r$
IF r$ <> "n" AND r$ <> "N" GOTO 1000
CLS
PRINT "                    UKUPNA BILANCA MASE      "
PRINT "--------------------------------------------------------"
PRINT "ULAZNI  MASENI PROTOK SOKA NARAN^E             (kg/h) ="; Qso
PRINT "IZLAZNI MASENI PROTOK KONCENTRATA SOKA         (kg/h) ="; QL
PRINT "IZLAZNI MASENI PROTOK PARA NARAN^INOG SOKA     (kg/h) ="; QV
PRINT
PRINT "                    BILANCA SUHE TVARI        "
PRINT "---------------------------------------------------------"
PRINT "MASENI UDIO SUHE TVARI NA ULAZU U UPARIVA^     (kg/kg) ="; xo
PRINT "MASENI UDIO SUHE TVARI NA IZLAZU IZ UPARIVA^A  (kg/kg) ="; x
PRINT
PRINT "                  UKUPNA BILANCA ENERGIJE     "
PRINT "---------------------------------------------------------"
PRINT "ULAZNI  TOK ENTALPIJE SOKA NARAN^E             (MJ/h) ="; Qso * fnCp(xo) * Tso / 1000
PRINT "ULAZNI  TOK ENTALPIJE ZASI^ENE VODENE PARE     (MJ/h) ="; Qp * fnip(Tpo) / 1000
PRINT "IZLAZNI TOK ENTALPIJE KONCENTRATA SOKA         (MJ/h) ="; QL * fnCp(x) * T / 1000
PRINT "IZLAZNI TOK ENTALPIJE UKAPLJENE VODENE PARE    (MJ/h) ="; Qp * fniv(T) / 1000
PRINT "IZLAZNI TOK ENTALPIJE PARA SOKA NARAN^E        (MJ/h) ="; QV * fnip(T) / 1000
PRINT "TEMPERATURA UPARIVANJA                            (C) ="; T
PRINT
PRINT "EFIKASNOST UPARIVANJA (kg otpareni sok/kg vodene pare) ="; QV / Qp
END